excel函數~文字轉換成日期時間格式

例如~

A1 9607081330 B1 2007/07/08 13:30

怎麼把A1轉換成B1~-而且要在B1一個儲存格就完成~要使用函數

還要參照A1~因為要拖曳公式~樞紐分析~資料剖析~都不是我要的~怎麼使用函數ㄋ~應該至少要四個函數以上搭配使用吧~

3 Answers

Rating
  • 1 decade ago
    Favorite Answer

    假設你的值在A1,請在B1輸入下列公式:

    =CONCATENATE(LEFT(A1,2)+1911,"/",MID(A1,3,2),"/",MID(A1,5,2),MID(A1,7,2),":",RIGHT(A1,2),)

    2008-06-17 12:45:19 補充:

    被解碼了,實際公式如下:

    =CONCATENATE(LEFT(A1,2)+1911,"/",MID(A1,3,2),"/",MID(A1,5,2),MID(A1,7,2),":",RIGHT(A1,2),)

    2008-06-17 12:48:39 補充:

    但此為文字變文字,卻無法四則運算!待會有空再解為數值!

    2008-06-17 12:57:27 補充:

    若要文字改為數值,則請在B1輸入下列公式:

    =DATE(LEFT(A1,2)+1911,MID(A1,3,2),MID(A1,5,2))+TIME(MID(A1,7,2),RIGHT(A1,2),0)

    此即可做四則運算,也可以加減日期或時間的運算!

    但需將儲存格的格式設為下面格式:

    yyyy/mm/dd hh:mm;@

    2008-06-17 12:59:57 補充:

    在測試中,你的A1的格式一定要為

    ###### ##:##

    000000 00:00

    否則會造成非日期時間格式的錯誤日期時間!

  • 顯栓
    Lv 7
    1 decade ago

    一個函數解決:

    =--(TEXT(A1+191100000000,"0000-00-00 00"":""00"))

    儲存格格式修改為 yyyy/mm/dd hh:mm;@

    將以上公式 複製 貼上就可用 複製比較準,用 KEY 的注意空格

    或再加個 TEXT

    =TEXT(--(TEXT(A1+191100000000,"0000-00-00 00"":""00")),"yyyy/mm/dd hh:mm")

    其他要計算也沒問題.

    2008-06-17 14:40:23 補充:

    CONCATENATE用法:

    =CONCATENATE(LEFT(A1,2)+1911,"/",MID(A1,3,2),"/",MID(A1,5,2)," ",MID(A1,7,2),":",RIGHT(A1,2),)

    省CONCATENATE

    =--(LEFT(A1,2)+1911&"/"&MID(A1,3,2)&"/"&MID(A1,5,2)&" "&MID(A1,7,2)&":"&RIGHT(A1,2))

    格式改一下!

  • piny
    Lv 7
    1 decade ago

    公式研究

    A欄通用格式即可

    B1=TEXT(DATE(LEFT(A1,2)+1911,MID(A1,3,2),MID(A1,5,2))+TIME(MID(A1,7,2),RIGHT(A1,2),0),"yyyy/mm/dd hh:mm")

Still have questions? Get your answers by asking now.