Anonymous
Anonymous asked in 電腦與網際網路軟體 · 1 decade ago

EXCEL 文字加總的問題

EXCEL 文字加總的問題

A B C

1

2

3

4

5

6

7

8

9

10

11

A 欄位會放不同的水果項目,但也有可能會重複 (文字欄位)

B 欄位 放入輸入者 設為 D E F (文字欄位)

C 欄位 輸入 數量 (數字欄位)

問題1- 如何加總 欄位A 需加總求水果項目數量 (重複的地方也為一計算單位)

問題2- 如何加總 欄位A 需加總求項目水果數量 (重複地方須不列入計算內)

問題3- 做篩選的動作, 選擇數入者時, 如何加總求得"輸入者"所輸入總水果項目

Update:

問題一 是要求輸入水果總項目數 (含重複的地方)

問題2 是要求輸入水果總項目數 (不含重複的地方)

問題3- 做篩選的動作,

可以做到 輸入水果總項目數 (含重複的地方)

可以做到 輸入水果總項目數 (不含重複的地方)

1 Answer

Rating
  • 1 decade ago
    Favorite Answer

    圖片參考:http://tw.yimg.com/i/tw/blog/rte/smiley_4.gif

    了解您的需求囉~

    最後的需求,還蠻難做到的~~

    假設您的資料如下圖黃色區域

    圖片參考:http://www.playblog.com.tw/_users/1/7/b/a/ab006930...

    1.水果總項目數 (含重複),C15公式為

    =COUNTA($A$2:$A$12)

    2.水果總項目數 (不重複),C16公式為

    {=SUMPRODUCT(IF($A$2:$A$12="",0,1/COUNTIF($A$2:$A$12,$A$2:$A$12)))}

    此為陣列公式,輸入公式時不含{、},公式輸入後按Ctrl+Shift+Enter結束,EXCEL會自動加上{、},成為陣列公式,請注意,此公式如未以陣列公式輸入,將不會有正確結果!!

    3.篩選後-水果總項目數 (含重複),C17公式為

    =SUBTOTAL(103,$A$2:$A$12)

    4.篩選後-水果總項目數 (不重複),C18公式為

    {=COUNT(IF(MATCH(IF(SUBTOTAL(3,OFFSET(A1,ROW($A$2:$A$12)-1,,)),$A$2:$A$12),IF(SUBTOTAL(3,OFFSET(A1,ROW($A$2:$A$12)-1,,)),$A$2:$A$12),)=IF(SUBTOTAL(3,OFFSET(A1,ROW($A$2:$A$12)-1,,)),ROW($A$2:$A$12)-1),ROW($A$2:$A$12)-1))}

    此為陣列公式,輸入公式時不含{、},公式輸入後按Ctrl+Shift+Enter結束,EXCEL會自動加上{、},成為陣列公式,請注意,此公式如未以陣列公式輸入,將不會有正確結果!!

    公式很複雜吧!!

    我也沒辦法,真是難~~~

    總算完成囉~~

    圖片參考:http://tw.yimg.com/i/tw/blog/rte/smiley_9.gif

    可以試試囉~~~~~~~~~~~~

    圖片參考:http://tw.yimg.com/i/tw/blog/rte/smiley_4.gif

Still have questions? Get your answers by asking now.